作者suny999 (满23篇了...)
看板Cad_Cae
标题Re: [问题] Autocad中polyline的图元串列资料
时间Fri May 29 14:58:39 2009
※ 引述《ggg888 (g8)》之铭言：
: 请问版上高手
: 我画一了一条polyline
: 其中还包括有圆孤的部份
: 取出这条线的串列资料後
: 发现关於圆孤的部份的资料为
: (10 409.77 199.567) (40 . 0.0) (41 . 0.0) (42 . -0.466828)
: 10应该是起点，请问42.代表的是什麽样的资料呢？
: 由於我想写一个程式，可以在这条polyline中每隔20m插入一个block
: 所以必须计算每段线段，包括孤长的长度，
: 藉此算出每个插入点的座标
: 请问各位有那些方法可以达到呢？
如果要写程式可以用下式：
先画一条聚合线或云形线，长度超过20
(setq dist 20)
(setq Curve-obj(vlax-ename->vla-object(car(entsel))))
(setq Prm (vlax-curve-getParamAtDist Curve-obj dist))
(setq Pt (vlax-curve-getPointAtParam Curve-obj Prm))
如此就可以取得20m处的座标值 Pt
当然这样的功能用内建的 measure可以达成，
所以要写程式就要有其必要性，不然这样好了，再求出该点法向斜率：
(setq Dri (vlax-curve-getFirstDeriv curve-obj Prm))
(setq Ang (+ (* pi 0.5) (angle '(0 0 0) Dri)))
如此就可以取得20m处的法向角度 Ang，可以调整插入图块的角度，
但这有什麽用吗？用 measure 插入图块用对齐不就好了！
写程式的用处在於：不等距分段、依里程标记
1. 可以不等距的分段，这点 measure 就很麻烦，
应该要支援 3@200, 2@150 表示式，试着设计输入回圈如下：
(defun GetList(/ ls tmp tmpls @)
(setq ls '())
(while (/= "" (setq tmp (getstring "hint:3@200=(200,200,200):")))
(setq tmpls '() ls
(append ls
(if (setq @ (vl-string-search "@" tmp))
(repeat(atoi tmp)
(setq tmpls (append tmpls (list (substr tmp (+ 2 @))))))
(list tmp) ) ) ) );_ eo while
(mapcar 'ATOF ls)) ;_eo GetList
(setq SegList (GetList))
如此可得各分段距离串列 SegList (ex: 200.0 200.0 200.0 150.0 150.0 300.0)
再写个小程式来累计串列：
(defun CumulativeList(oList / ls add nList)
(setq ls 0.0 nList '())
(foreach add oList(setq ls(+ ls add)nList(append nList(list ls)))))
(setq CumList (CumulativeList SegList))
如此可得累进距离串列 CumList (ex: 200.0 400.0 600.0 750.0 900.0 1200.0)
2. 可以在每个分段依其里程长度作动态标示(ex:Sec.2 ,Len=200.0, Loc=400.)，
下面以画垂线示范一个简单完整的程式，也可以改为插入图块就更简单：
(vl-load-com)
(defun c:meas()
(setq MSpace(vla-get-ModelSpace(vla-get-ActiveDocument(vlax-get-acad-object)))
SegList (ms:GetList)
CumList (ms:CumulativeList SegList)
Offset (getreal "Offset distance:")
Extend (getreal "Extend length:")
Curve-obj(vlax-ename->vla-object(car(entsel)))
n 0)
(foreach Loc CumList
(setq
Prm (vlax-curve-getParamAtDist curve-obj Loc)
Pt1 (vlax-curve-getPointAtParam curve-obj Prm)
Dri (vlax-curve-getFirstDeriv curve-obj Prm)
Ang (+ (* pi 0.5) (angle '(0 0 0) Dri))
Pt2 (polar Pt1 Ang Offset)
Pt1 (polar Pt2 Ang Extend)
Str (strcat " Sec."(itoa n)", Len="(rtos(nth n SegList))", Loc="(rtos Loc))
Obj (vla-AddLine MSpace (vlax-3d-point Pt2) (vlax-3d-point Pt1))
Obj (vla-AddText MSpace Str (vlax-3d-point Pt2) (getvar "textsize"))
n (1+ n) )
(vla-put-Rotation Obj (+ Ang pi)) ));_eo meas
(defun ms:GetList(/ ls tmp tmpls @)
(setq ls '())
(while (/= "" (setq tmp (getstring "hint:3@200=(200,200,200):")))
(setq tmpls '() ls
(append ls
(if (setq @ (vl-string-search "@" tmp))
(repeat(atoi tmp)
(setq tmpls (append tmpls (list (substr tmp (+ 2 @))))))
(list tmp) ) ) ) );_ eo while
(mapcar 'ATOF ls)) ;_eo GetList
(defun ms:CumulativeList(oList / ls add nList)
(setq ls 0.0 nList '())
(foreach add oList(setq ls(+ ls add)nList(append nList(list ls)))))
执行范例：
先画一条spline, 其长度约1000以上, 执行 meas
输入分段长度:0 3@200 2@150 <enter>
输入Offset:-100
输入extend:200
选取曲线:
OK
目前这是个非常阳春的曲线分段程式，并无设定起点功能，
只要加入check指定起点是否为曲线起点就可以了，
如果为否就令 CumList = 曲线长 - CumList 即可，
不过 Visual Lisp 有一点很奇怪的地方，
就是 ActiveX 里面 polyline 有 length property，
可以用 (setq Curve-Len(vla-get-length Curve-obj)) 取得。
但是 Spline 却没有 length property，
故 spline 的曲线长必须改为下式：
(setq Curve-Len(vlax-curve-getDistAtParam curve-obj
(vlax-curve-getEndParam curve-obj)))
这点真是够了，连 spline 的曲线长都和 ls 指令不太相同。
--
小弟初学 Lisp 若有写错请见谅！
--
※ 发信站: 批踢踢实业坊(ptt.cc)
◆ From: 118.169.200.130
※ 编辑: suny999 来自: 118.169.200.130 (05/29 14:59)